1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "exp10l.s"
  30 
  31 #include "libm.h"
  32 
  33         .data
  34         .align  16
  35 lt2_hi: .4byte  0xfbd00000, 0x9a209a84, 0x3ffd, 0x0
  36 lt2_lo: .4byte  0x653f4837, 0x8677076a, 0xbfc9, 0x0
  37 
  38         ENTRY(exp10l)
  39         movl    16(%rsp),%ecx           / cx <--sign&bexp(x)
  40         andl    $0x7fff,%ecx            / ecx <-- zero_xtnd(bexp(x))
  41         cmpl    $0x3ffd,%ecx            / Is |x| < log10(2)?
  42         jb      .shortcut               / If so, take a shortcut.
  43         je      .check_tail             / maybe |x| only slightly < log10(2)
  44 .general_case:                          / Here, |x| > log10(2) or x is NaN
  45         cmpl    $0x7fff,%ecx            / bexp(|x|) = bexp(INF)?
  46         je      .not_finite             / if so, x is not finite
  47         cmpl    $0x400e,%ecx            / |x| < 32768 = 2^15?
  48         jb      .finite_non_special     / if so, proceed with argument reduction
  49         fldt    8(%rsp)                 / x
  50         fld1                            / 1, x
  51         jmp     1f
  52 .finite_non_special:                    / Here, log10(2) < |x| < 2^15
  53         fldt    8(%rsp)                 / x
  54         fld     %st(0)                  / x, x
  55         fldl2t                          / log2(10), x, x
  56         fmulp                           / z := x*log2(10), x
  57         frndint                         / [z], x
  58         fst     %st(2)                  / [z], x, [z]
  59         PIC_SETUP(1)
  60         fldt    PIC_L(lt2_hi)           / lt2_hi, [z], x, [z]
  61         fmulp                           / [z]*lt2_hi, x, [z]
  62         fsubrp  %st,%st(1)              / x-[z]*lt2_hi, [z]
  63         fldt    PIC_L(lt2_lo)           / lt2_lo, x-[z]*lt2_hi, [z]
  64         PIC_WRAPUP
  65         fmul    %st(2),%st              / [z]*lt2_lo, x-[z]*lt2_hi, [z]
  66         fsubrp  %st,%st(1)              / r := x-[z]*log10(2), [z]
  67         fldl2t                          / log2(10), r, [z]
  68         fmulp                           / f := r*log2(10), [z]
  69         f2xm1                           / 2^f-1,[z]
  70         fld1                            / 1, 2^f-1, [z]
  71         faddp   %st,%st(1)              / 2^f, [z]
  72 1:
  73         fscale                          / 10^x, [z]
  74         fstp    %st(1)
  75         ret
  76 
  77 .check_tail:
  78         movl    12(%rsp),%ecx           / ecx <-- hi_32(sgnfcnd(x))
  79         cmpl    $0x9a209a84,%ecx        / Is |x| < log10(2)?
  80         ja      .finite_non_special
  81         jb      .shortcut
  82         movl    8(%rsp),%edx            / edx <-- lo_32(sgnfcnd(x))
  83         cmpl    $0xfbcff798,%edx        / Is |x| slightly > log10(2)?
  84         ja      .finite_non_special     / branch if |x| slightly > log10(2)
  85 .shortcut:
  86         / Here, |x| < log10(2), so |z| = |x/log10(2)| < 1
  87         / whence z is in f2xm1's domain.
  88         fldt    8(%rsp)                 / x
  89         fldl2t                          / log2(10), x
  90         fmulp                           / z := x*log2(10)
  91         f2xm1                           / 2^z-1
  92         fld1                            / 1, 2^z-1
  93         faddp   %st,%st(1)              / 10^x
  94         ret
  95 
  96 .not_finite:
  97         movl    12(%rsp),%ecx           / ecx <-- hi_32(sgnfcnd(x))
  98         cmpl    $0x80000000,%ecx        / hi_32(sgnfcnd(x)) = hi_32(sgnfcnd(INF))?
  99         jne     .NaN_or_pinf            / if not, x is NaN or unsupp.
 100         movl    8(%rsp),%edx            / edx <-- lo_32(sgnfcnd(x))
 101         cmpl    $0,%edx                 / lo_32(sgnfcnd(x)) = 0?
 102         jne     .NaN_or_pinf            / if not, x is NaN
 103         movl    16(%rsp),%eax           / ax <-- sign&bexp((x))
 104         andl    $0x8000,%eax            / here, x is infinite, but +/-?
 105         jz      .NaN_or_pinf            / branch if x = +INF
 106         fldz                            / Here, x = -inf, so return 0
 107         ret
 108 
 109 .NaN_or_pinf:
 110         / Here, x = NaN or +inf, so load x and return immediately.
 111         fldt    8(%rsp)
 112         ret
 113         .align  16
 114         SET_SIZE(exp10l)