1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "ilogb.s"
  30 
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(ilogb,function)
  33 #include "libm_synonyms.h"
  34 #include "xpg6.h"
  35 
  36         .data
  37         .align  8
  38 two52:  .long   0x0,0x43300000  / 2**52
  39 
  40         ENTRY(ilogb)
  41         movl    8(%esp),%eax            / eax <-- hi_32(x)
  42         andl    $0x7fffffff,%eax        / eax <-- hi_32(abs(x))
  43         testl   $0x7ff00000,%eax        / is bexp(x) 0?
  44         jz      .bexp_0                 / jump if x is 0 or subnormal
  45                                         / biased exponent is non-zero
  46         cmpl    $0x7ff00000,%eax        / is bexp(x) 0x7ff?
  47         jae     .bexp_all_1             / jump if x is NaN or Inf
  48         shrl    $20,%eax                / eax <-- bexp(x)
  49         subl    $1023,%eax              / unbias exponent by 1023
  50         ret
  51 
  52 .bexp_all_1:
  53         movl    $0x7fffffff,%eax        / x is NaN or inf, so return 0x7fffffff
  54         jmp     0f
  55 
  56 .bexp_0:
  57         orl     4(%esp),%eax            / test whether x is 0
  58         jnz     .ilogb_subnorm
  59         movl    $0x80000001,%eax        / x is +/-0, so return 0x80000001
  60 0:
  61         PIC_SETUP(0)
  62         PIC_G_LOAD(movzwl,__xpg6,ecx)
  63         PIC_WRAPUP
  64         andl    $_C99SUSv3_ilogb_0InfNaN_raises_invalid,%ecx
  65         cmpl    $0,%ecx
  66         je      1f
  67         fldz
  68         fdivp   %st,%st(0)              / raise invalid as per SUSv3
  69 1:
  70         ret
  71 
  72 .ilogb_subnorm:                         / subnormal input
  73         fldl    4(%esp)                 / push x
  74         PIC_SETUP(1)
  75         fmull   PIC_L(two52)            / x*2**52
  76         PIC_WRAPUP
  77         subl    $8,%esp                 / set up storage area
  78         fstpl   (%esp)                  / store x*2**52 in storage are
  79         movl    $0x7ff00000,%eax
  80         andl    4(%esp),%eax
  81         shrl    $20,%eax                / extract exponent of x*2**52
  82         subl    $1075,%eax              / unbias it by 1075 (= 1023 + 52)
  83         addl    $8,%esp
  84         ret
  85         .align  4
  86         SET_SIZE(ilogb)