1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "exp2f.s"
  30 
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(exp2f,function)
  33 #include "libm_synonyms.h"
  34 
  35         ENTRY(exp2f)
  36         movl    4(%esp),%ecx            / ecx <-- x
  37         andl    $0x7fffffff,%ecx        / ecx <-- |x|
  38         cmpl    $0x3f800000,%ecx        / Is |x| <= 1?
  39         jbe     .shortcut               / If so, take a shortcut.
  40         cmpl    $0x7f800000,%ecx        / |x| >= INF?
  41         jae     .not_finite             / if so, x is not finite
  42         flds    4(%esp)                 / push arg
  43         fld     %st(0)                  / duplicate stack top
  44         frndint                         / [x],x
  45         fucom                           / x integral?
  46         fstsw   %ax
  47         sahf
  48         je      .x_integral             / branch if x integral
  49         fxch                            / x, [x]
  50         fsub    %st(1),%st              / x-[x], [x]
  51         f2xm1                           / 2**(x-[x])-1, [x]
  52         fld1                            / 1,2**(x-[x])-1, [x]
  53         faddp   %st,%st(1)              / 2**(x-[x]), [x]
  54         fscale                          / 2**x = 2**(arg), [x]
  55         fstp    %st(1)
  56         ret
  57 
  58 .x_integral:                            / here, x is integral
  59         fstp    %st(0)                  / ,x
  60         fld1                            / 1 = 2**0, x
  61         fscale                          / 2**(0 + x) = 2**x, x
  62         fstp    %st(1)                  / 2**x
  63         ret
  64 
  65 .shortcut:
  66         / Here, |x| <= 1,
  67         / whence x is in f2xm1's domain.
  68         flds    4(%esp)                 / push x
  69         f2xm1                           / 2**x - 1
  70         fld1                            / 1,2**x - 1
  71         faddp   %st,%st(1)              / 2**x
  72         ret
  73 
  74 .not_finite:
  75         ja      .NaN_or_pinf            / branch if x is NaN 
  76         movl    4(%esp),%eax            / eax <-- x
  77         andl    $0x80000000,%eax        / here, x is infinite, but +/-?
  78         jz      .NaN_or_pinf            / branch if x = +INF
  79         fldz                            / Here, x = -inf, so return 0
  80         ret
  81 
  82 .NaN_or_pinf:
  83         / Here, x = NaN or +inf, so load x and return immediately.
  84         flds    4(%esp)
  85         fwait
  86         ret
  87         .align  4
  88         SET_SIZE(exp2f)