1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "asin.s"
  30 
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(asin,function)
  33 #include "libm_synonyms.h"
  34 #include "libm_protos.h"
  35 
  36 #undef fabs
  37 
  38         ENTRY(asin)
  39         fldl    4(%esp)                 / push x
  40         fld1                            / push 1
  41         fld     %st(1)                  / x , 1 , x
  42         fabs                            / |x| , 1 , x
  43         fucomp
  44         fstsw  %ax
  45         sahf     
  46         ja      .ERR
  47         fadd    %st(1),%st              / 1+x,x
  48         fld1                            / 1,1+x,x
  49         fsub    %st(2),%st              / 1-x,1+x,x
  50         fmulp   %st,%st(1)              / (1-x)*(1+x),x
  51         fsqrt                           / sqrt((1-x)/(1+x)),x
  52         fpatan                          / atan(x/sqrt((1-x)/(1+x)))
  53         ret
  54 
  55 .ERR:
  56         / |x| > 1
  57         pushl   %ebp
  58         movl    %esp,%ebp
  59         PIC_SETUP(1)
  60         fstp    %st(0)                  / x
  61         fstp    %st(0)                  / empty NPX stack
  62         pushl   $2
  63         pushl   12(%ebp)                / high x
  64         pushl   8(%ebp)                 / low x
  65         pushl   12(%ebp)                / high x
  66         pushl   8(%ebp)                 / low x
  67         call    PIC_F(_SVID_libm_err)   / report SVID result/error
  68         addl    $20,%esp
  69         PIC_WRAPUP
  70         leave
  71         ret
  72         .align  4
  73         SET_SIZE(asin)