1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "acos.s"
  30 
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(acos,function)
  33 #include "libm_synonyms.h"
  34 #include "libm_protos.h"
  35 
  36 #undef fabs
  37 
  38         ENTRY(acos)
  39         fldl    4(%esp)                 / push x
  40         fld1                            / push 1
  41         fld     %st(1)                  / x , 1 , x
  42         fabs                            / |x| , 1 , x
  43         fucomp
  44         fstsw   %ax
  45         sahf
  46         ja      .ERR
  47         fadd    %st(1),%st              / 1+x,x
  48         fldz
  49         fucomp  
  50         fstsw   %ax
  51         sahf
  52         jp      .L1
  53         jne     .L1
  54         / x is -1 
  55         fstp    %st(0)                  / -1
  56         fstp    %st(0)                  / empty NPX stack
  57         fldpi
  58         ret
  59 .L1:
  60         fxch    %st(1)                  / x,1+x
  61         fld1                            / 1,x,1+x
  62         fsubp   %st,%st(1)              / 1-x,1+x
  63         fdivp   %st,%st(1)              / (1-x)/(1+x)
  64         fsqrt
  65         fld1                            / 1,sqrt((1-x)/(1+x))
  66         fpatan
  67         fadd    %st(0),%st
  68         ret
  69 
  70 .ERR:
  71         / |x| > 1
  72         pushl   %ebp
  73         movl    %esp,%ebp
  74         PIC_SETUP(1)
  75         fstp    %st(0)                  / x
  76         fstp    %st(0)                  / empty NPX stack
  77         pushl   $1
  78         pushl   12(%ebp)                / high x
  79         pushl   8(%ebp)                 / low x
  80         pushl   12(%ebp)                / high x
  81         pushl   8(%ebp)                 / low x
  82         call    PIC_F(_SVID_libm_err)   / report SVID result/error
  83         addl    $20,%esp
  84         PIC_WRAPUP
  85         leave
  86         ret
  87         .align  4
  88         SET_SIZE(acos)