1 OUTPUT_FORMAT("elf64-x86-64-sol2", "elf64-x86-64-sol2", "elf64-x86-64-sol2")
   2 OUTPUT_ARCH(i386:x86-64)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   /* Read-only sections, merged into text segment: */
   7   . = 0;
   8   ImageBase = .;
   9   .hash : { *(.hash) }  /* this MUST come first! */
  10   . = ALIGN(4096);
  11   .eh_frame :
  12   {
  13     *(.eh_frame)
  14   }
  15   . = ALIGN(4096);
  16   .text         : {
  17     multiboot.o(.text)
  18     *(.text .stub .text.* .gnu.linkonce.t.*)
  19     /* .gnu.warning sections are handled specially by elf32.em. */
  20     *(.gnu.warning)
  21     *(.plt)
  22   } =0xCCCCCCCC
  23   . = ALIGN(4096);
  24   .data         : {
  25     *(.rodata .rodata.* .gnu.linkonce.r.*)
  26     *(.rodata1)
  27     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  28     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  29     *(.opd)
  30     *(.data .data.* .gnu.linkonce.d.*)
  31     *(.data1)
  32     *(.plabel)
  33     *(.dynbss)
  34     *(.bss .bss.* .gnu.linkonce.b.*)
  35     *(COMMON)
  36   }
  37   . = ALIGN(4096);
  38   set_Xcommand_set      : {
  39     __start_set_Xcommand_set = .;
  40     *(set_Xcommand_set)
  41     __stop_set_Xcommand_set = .;
  42   }
  43   set_Xficl_compile_set : {
  44     __start_set_Xficl_compile_set = .;
  45     *(set_Xficl_compile_set)
  46     __stop_set_Xficl_compile_set = .;
  47   }
  48   . = ALIGN(4096);
  49   __gp = .;
  50   .sdata        : {
  51     *(.got.plt .got)
  52     *(.sdata .sdata.* .gnu.linkonce.s.*)
  53     *(dynsbss)
  54     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  55     *(.scommon)
  56   }
  57   . = ALIGN(4096);
  58   .dynamic      : { *(.dynamic) }
  59   . = ALIGN(4096);
  60   .rela.dyn     : {
  61     *(.rela.data*)
  62     *(.rela.got)
  63     *(.rela.stab)
  64     *(.relaset_*)
  65   }
  66   . = ALIGN(4096);
  67   .reloc        : { *(.reloc) }
  68   . = ALIGN(4096);
  69   .dynsym       : { *(.dynsym) }
  70   . = ALIGN(4096);
  71   .dynstr       : { *(.dynstr) }
  72 }