1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "rndintl.s"
  30 
  31 #include "libm.h"
  32 
  33 #undef fabs
  34 
  35         ENTRY(aintl)
  36         movl    %esp,%eax
  37         subl    $8,%esp
  38         fstcw   -8(%eax)
  39         fldt    4(%eax)
  40         movw    -8(%eax),%cx
  41         orw     $0x0c00,%cx
  42         movw    %cx,-4(%eax)
  43         fldcw   -4(%eax)                / set RD = to_zero
  44         frndint
  45         fstcw   -4(%eax)
  46         movw    -4(%eax),%dx
  47         andw    $0xf3ff,%dx
  48         movw    -8(%eax),%cx
  49         andw    $0x0c00,%cx
  50         orw     %dx,%cx
  51         movw    %cx,-8(%eax)
  52         fldcw   -8(%eax)                / restore RD
  53         addl    $8,%esp
  54         ret
  55         .align  4
  56         SET_SIZE(aintl)
  57 
  58         ENTRY(irintl)
  59         movl    %esp,%ecx
  60         subl    $8,%esp
  61         fldt    4(%ecx)                 / load x
  62         fistpl  -8(%ecx)                / [x]
  63         fwait
  64         movl    -8(%ecx),%eax
  65         addl    $8,%esp
  66         ret
  67         .align  4
  68         SET_SIZE(irintl)
  69 
  70         .data
  71         .align  4
  72 half:   .float  0.5
  73 
  74         ENTRY(anintl)
  75 .Lanintl:
  76         movl    %esp,%ecx
  77         subl    $8,%esp
  78         fstcw   -8(%ecx)
  79         fldt    4(%ecx)
  80         movw    -8(%ecx),%dx
  81         andw    $0xf3ff,%dx
  82         movw    %dx,-4(%ecx)
  83         fldcw   -4(%ecx)                / set RD = to_nearest
  84         fld     %st(0)
  85         frndint                         / [x],x
  86         fstcw   -4(%ecx)
  87         movw    -4(%ecx),%dx
  88         andw    $0xf3ff,%dx
  89         movw    -8(%ecx),%ax
  90         andw    $0x0c00,%ax
  91         orw     %dx,%ax
  92         movw    %ax,-8(%ecx)
  93         fldcw   -8(%ecx)                / restore RD
  94         fucom                           / check if x is already an integer
  95         fstsw   %ax
  96         sahf
  97         jp      .L0
  98         je      .L0
  99         fxch                            / x,[x]
 100         fsub    %st(1),%st              / x-[x],[x]
 101         fabs                            / |x-[x]|,[x]
 102         PIC_SETUP(1)
 103         fcoms   PIC_L(half)
 104         PIC_WRAPUP
 105         fnstsw  %ax
 106         sahf
 107         jae     .halfway                / if |x-[x]| = 0.5 goto halfway, 
 108                                         / most cases will not take branch.
 109 .L0:
 110         addl    $8,%esp
 111         fstp    %st(0)
 112         ret
 113 .halfway:
 114         / x = n+0.5, recompute anint(x) as x+sign(x)*0.5
 115         fldt    4(%ecx)                 / x, 0.5, [x]
 116         movw    12(%ecx),%ax            / sign+exp part of x
 117         andw    $0x8000,%ax             / look at sign bit
 118         jnz     .x_neg
 119         faddp
 120         addl    $8,%esp
 121         fstp    %st(1)
 122         ret
 123 .x_neg:
 124         / here, x is negative, so return x-0.5
 125         fsubp   %st,%st(1)              / x-0.5,[x]
 126         addl    $8,%esp
 127         fstp    %st(1)
 128         ret
 129         .align  4
 130         SET_SIZE(anintl)
 131 
 132         ENTRY(nintl)
 133         pushl   %ebp
 134         movl    %esp,%ebp
 135         subl    $8,%esp
 136         pushl   16(%ebp)
 137         pushl   12(%ebp)
 138         pushl   8(%ebp)
 139         call    .Lanintl                /// LOCAL
 140         fistpl  -8(%ebp)
 141         fwait
 142         movl    -8(%ebp),%eax
 143         leave
 144         ret
 145         .align  4
 146         SET_SIZE(nintl)