1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28 
  29         .file "ilogbf.s"
  30 
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(ilogbf,function)
  33 #include "libm_synonyms.h"
  34 #include "xpg6.h"
  35 
  36         .data
  37         .align  8
  38 two23:  .long   0x4b000000              / 2**23
  39 
  40         ENTRY(ilogbf)
  41         movl    4(%esp),%eax            / eax <-- x
  42         testl   $0x7f800000,%eax        / is bexp(x) 0?
  43         jz      .bexp_0                 / jump if x is 0 or subnormal
  44                                         / here, biased exponent is non-zero
  45         andl    $0x7fffffff,%eax        / eax <-- abs(x)
  46         cmpl    $0x7f800000,%eax        / is bexp(x) 0xff?
  47         jae     .bexp_all_1             / jump if x is NaN or Inf
  48         shrl    $23,%eax                / eax <-- zero_xtnd(bexp(x))
  49         subl    $127,%eax               / unbias exponent by 127
  50         ret
  51 
  52 .bexp_all_1:
  53         movl    $0x7fffffff,%eax        / x is NaN or inf, so return 0x7fffffff
  54         jmp     0f
  55 
  56 .bexp_0:
  57         andl    $0x7fffffff,%eax        / eax <-- abs(x), and
  58                                         / ZF = 1 iff x = 0.0
  59         jnz     .ilogb_subnorm
  60         movl    $0x80000001,%eax        / x is +/-0, so return 0x80000001
  61 0:
  62         PIC_SETUP(0)
  63         PIC_G_LOAD(movzwl,__xpg6,ecx)
  64         PIC_WRAPUP
  65         andl    $_C99SUSv3_ilogb_0InfNaN_raises_invalid,%ecx
  66         cmpl    $0,%ecx
  67         je      1f
  68         fldz
  69         fdivp   %st,%st(0)              / raise invalid as per SUSv3
  70 1:
  71         ret
  72 
  73 .ilogb_subnorm:                         / subnormal input
  74         flds    4(%esp)                 / push x
  75         PIC_SETUP(1)
  76         fmuls   PIC_L(two23)            / x*2**23; rebias x by 127+23,
  77                                         /          instead of 127
  78         PIC_WRAPUP
  79         subl    $4,%esp                 / set up storage area
  80         fstps   (%esp)                  / store x*2**23 in storage area
  81         fwait                           / (shouldn't raise exception, but
  82                                         / just in case)
  83         movl    $0x7f800000,%eax        / eax <-- single_bexp_mask
  84         andl    (%esp),%eax             / eax[23..30]  <-- bexp(x*2**23),
  85                                         / rest_of(eax) <-- 0
  86         shrl    $23,%eax                / eax <-- zero_xtnd(bexp(x*2**23))
  87         subl    $150,%eax               / unbias rebiased x by 150 (= 127 + 23)
  88         addl    $4,%esp                 / restore stack for caller
  89         ret
  90         .align  4
  91         SET_SIZE(ilogbf)